Windows 2000 프로/서버에 설치된 Windows 2000 지원 도구의 Netdom과 $PosLen, PsExec를 이용해서 처리할 수 있다. 다음은 실제 이작업을 수행하는 ExeAll.bat이다.
사용형식은 다음과 같다.
ExeAll Domain Account Password Object Batch ReportFile
여기서:
Domain NetBIOS 도메인 이름.
Account 도메인내 도메인 관리자 계정. "Domain\Account"를 참조하는데 사용.
Password "Domain\Account" 계정의 암호.
Object 포함될 컴퓨터의 유형 목록:
W - 멤버 웍스테이션
S - 멤버 서버
P - 주 도메인 제어기(PDC)
D - 도메인 제어기
Batch 프로그램의 완전한 UNC 경로(\\Server\Share\program).
다음은 ExeAll의 내용이다:
@echo off
setlocal
if {%1} EQU {} goto syntax
if {%2} EQU {} goto syntax
if {%3} EQU {} goto syntax
if {%4} EQU {} goto syntax
if {%5} EQU {} goto syntax
if {%6} EQU {} goto syntax
set pw=%3
set pw=%pw:"=%
set Object=%4
set object=%object:"=%
set batch=%5
set report=%6
set domacct=%1\%2
set domacct="%domacct:"=%"
if NOT "%batch:~1,1%" EQU "" goto syntax
if NOT exist %batch% goto syntax
if exist %report% del /q %report%
set /a cnt=0
:loop
call $poslen %object% %cnt% 1
if /i "%$substring%" EQU "W" set ot=WORKSTATION&goto loopa
if /i "%$substring%" EQU "S" set ot=SERVER&goto loopa
if /i "%$substring%" EQU "P" set ot=PDC&goto loopa
if /i "%$substring%" EQU "D" set ot=DC&goto loopa
if %cnt% EQU 0 goto syntax
endlocal
goto :EOF
:loopa
set /a cnt=%cnt% + 1
For /f "Skip=1 Tokens=1" %%i in ('netdom query /domain %ot%') do call :computer "%%i"
goto loop
:syntax
@echo Syntax: ExeAll Domain Account Password Object Batch
endlocal
goto :EOF
:computer
set machine=%1
set machine=%machine:"=%
if "%machine%" EQU "The" goto end
if "%machine%" EQU "Directory" goto end
for /f "Tokens=*" %%j in ('@echo %%machine:.%USERDNSDOMAIN%^=%%') do set machine=%%j
@echo Begin Computer=%machine%>>%Report%
PsExec \\%machine% -u %domacct% -p %pw% %batch%>>%Report%
:end
사용예:
로컬 관리자 그룹에 도메인 사용자 그룹을 추가하기위해 도메인내 각사용자의 웍스테이션과 서버에서 다음 절차를 수행한다.
- 다음 내용을 포함하는 admin.bat을 \\Server\Share에 생성한다.
@echo off
net localgroup Administrators "<YourDomainName>\Domain Users" /ADD
- 다음 명령을 실행한다.
ExeAll Domain Account Password WS \\Server\Share\admin.bat
정보: 필요한 모든 도구가 설치된 경우 자신의 컴퓨터에서 실행할 수 있다.
(